ESP32C3 SuperMini

• CPU: ESP32-C3, 32-bit RISC-V single-core processor, up to 160 MHz
• Wi-Fi: IEEE 802.11 b/g/n, 2.4 GHz
• Bluetooth: Bluetooth 5.0 LE
• Memory: 400 KB SRAM, 384 KB ROM, built-in 4 MB Flash
• Chip Model: ESP32C3FN4
• Interfaces: 1 x I2C, 1 x SPI, 2 x UART, 11 x GPIO/PWM, 4 x ADC
• Power Features: deep sleep power consumption around 43 μA
• Form Factor: single-sided SMT design, compact and easy to integrate
• Board Size: 22.52 x 18 mm

If an external power supply is required, connect the positive terminal to 5V and the negative terminal to GND. The board supports approximately 3.3V to 6V input.

Important: Do not connect USB and external power at the same time. Choose only one power source.

If you want to use an external antenna, connect it according to the diagram below.

You will need:

• 1 x ESP32C3 SuperMini
• 1 x computer
• 1 x USB Type-C data cable

Connect the board to your computer using a USB Type-C data cable.

1. Download and install the latest Arduino IDE: Arduino IDE Download
2. If the official download is slow, you can also use Arduino Community Mirror
3. Open Arduino IDE
4. Add the ESP32 board package URL in File > Preferences > Additional Boards Manager URLs:

https://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_index.json

1. In Tools > Board > Boards Manager, search for esp32 and install the latest package
2. In Tools > Board > ESP32 Arduino, select ESP32C3 Dev Module
3. In Tools > Port, select the COM/serial port for the connected board

Copy the following code into Arduino IDE and upload it to the board:

// define led according to pin diagram
int led = 8;
 
void setup() {
  // initialize digital pin led as an output
  pinMode(led, OUTPUT);
}
 
void loop() {
  digitalWrite(led, HIGH);   // turn the LED off
  delay(1000);               // wait for a second
  digitalWrite(led, LOW);    // turn the LED on
  delay(1000);               // wait for a second
}

After uploading, the on-board blue LED should blink with a 1-second interval.

This example starts a simple web server so you can control the LED from a browser.

/*
 WiFi Web Server LED Blink
 
 A simple web server that lets you blink an LED via the web.
 This sketch will print the IP address of your WiFi Shield (once connected)
 to the Serial monitor. From there, you can open that address in a web browser
 to turn on and off the LED on pin 5.
 
 If the IP address of your shield is yourAddress:
 http://yourAddress/H turns the LED on
 http://yourAddress/L turns it off
 
 This example is written for a network using WPA2 encryption. For insecure
 WEP or WPA, change the Wifi.begin() call and use Wifi.setMinSecurity() accordingly.
 
 Circuit:
 * WiFi shield attached
 * LED attached to pin 5
 
 created for arduino 25 Nov 2012
 by Tom Igoe
 
ported for sparkfun esp32 
31.01.2017 by Jan Hendrik Berlin
 
 */
 
#include <WiFi.h>
 
const char* ssid     = "Onion3";  // Set WiFi name
const char* password = "asdfghjkl";  // Set WiFi password
 
WiFiServer server(80);
 
void setup()
{
    Serial.begin(115200);
    pinMode(8, OUTPUT);      // set the LED pin mode
 
    delay(10);
 
    // We start by connecting to a WiFi network
 
    Serial.println();
    Serial.println();
    Serial.print("Connecting to ");
    Serial.println(ssid);
 
    WiFi.begin(ssid, password);
 
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }
 
    Serial.println("");
    Serial.println("WiFi connected.");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());
 
    server.begin();
 
}
 
void loop(){
 WiFiClient client = server.available();   // listen for incoming clients
 
  if (client) {                             // if you get a client,
    Serial.println("New Client.");           // print a message out the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        if (c == '\n') {                    // if the byte is a newline character
 
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println();
 
            // the content of the HTTP response follows the header:
            client.print("Click <a href=\"/H\">here</a> to turn the LED on pin 8 on.<br>");
            client.print("Click <a href=\"/L\">here</a> to turn the LED on pin 8 off.<br>");
 
            // The HTTP response ends with another blank line:
            client.println();
            // break out of the while loop:
            break;
          } else {    // if you got a newline, then clear currentLine:
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
 
        // Check to see if the client request was "GET /H" or "GET /L":
        if (currentLine.endsWith("GET /H")) {
          digitalWrite(8, HIGH);               // GET /H turns the LED on
        }
        if (currentLine.endsWith("GET /L")) {
          digitalWrite(8, LOW);                // GET /L turns the LED off
        }
      }
    }
    // close the connection:
    client.stop();
    Serial.println("Client Disconnected.");
  }
}

• ESP32C3 SuperMini MicroPython Firmware Download
• MicroPython Firmware Download Tutorial

• Open Source ESP32 Arduino Tutorial
• Open Source ESP32 MicroPython Tutorial
• ESP32-C3 Official Learning Resources
• ESP32-C3 Collected Learning Resources

Enter download mode in one of the following ways:

• Hold BOOT while powering on.
• Hold BOOT, press RESET, release RESET, then release BOOT.

After upload completes successfully, press the RESET button once.

See: JTAG/serial debug unit Display Solution

Set USB CDC On Boot to Enabled in the Arduino toolbar.

For more questions and project ideas, visit the community forum:

• Forum
• QQ technical exchange group: 522420541